Resumen
Para calcular el impuesto sobre la renta total en función de varios tramos impositivos, puede usar BUSCARV y una tabla de tasas estructurada como se muestra en el ejemplo. La fórmula en G5 es:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1)
donde "inc" (G4) y "tasas" (B5: D11) son rangos con nombre, y la columna D es una columna auxiliar que calcula el impuesto total acumulado en cada tramo.
Antecedentes y contexto
El sistema de impuestos de los Estados Unidos es "progresivo", lo que significa que las personas con ingresos imponibles más altos pagan una tasa impositiva federal más alta. Las tasas se evalúan entre paréntesis definidos por un umbral superior e inferior. La cantidad de ingresos que cae en un tramo dado se grava a la tasa correspondiente para ese tramo. A medida que aumenta la renta imponible, la renta se grava en más tramos impositivos. Por tanto, muchos contribuyentes pagan varias tasas diferentes.
En el ejemplo que se muestra, los tramos y las tasas impositivas son para contribuyentes únicos en los Estados Unidos para el año fiscal 2019. La siguiente tabla muestra los cálculos manuales para un ingreso imponible de $ 50,000:
| Soporte | Cálculo | Impuesto |
|---|---|---|
| 10% | ($ 9,700 - $ 0) x 10% | $ 970,00 |
| 12% | ($ 39,475 - $ 9,700) x 12% | $ 3,573.00 |
| 22% | ($ 50 000- $ 39 475) x 22% | $ 2,315.50 |
| 24% | N / A | 0,00 $ |
| 32% | N / A | 0,00 $ |
| 35% | N / A | 0,00 $ |
| 37% | N / A | 0,00 $ |
Por lo tanto, el impuesto total es de $ 6,858.50. (mostrado como 6,859 en el ejemplo mostrado).
Notas de configuración
1. Esta fórmula depende de la función BUSCARV en "modo de coincidencia aproximada". En el modo de coincidencia aproximada, BUSCARV explorará los valores de búsqueda en una tabla (que debe ordenarse en orden ascendente) hasta encontrar un valor más alto. Luego, "retrocederá" y devolverá un valor de la fila anterior. En el caso de una coincidencia exacta, BUSCARV devolverá resultados de la fila coincidente.
2. Para que BUSCARV recupere los montos de impuestos acumulados reales, estos se han agregado a la tabla como una columna auxiliar en la columna D. La fórmula en D6, copiada, es:
=((B6-B5)*C5)+D5
En cada fila, esta fórmula aplica la tasa de la fila anterior a los ingresos en ese rango.
3. Para facilitar la lectura, se definen los siguientes rangos con nombre: "inc" (G4) y "tasas" (B5: D11).
Explicación
En G5, el primer VLOOKUP está configurado para recuperar el impuesto acumulado a la tasa marginal con estas entradas:
- El valor de búsqueda es "inc" (G4)
- La tabla de búsqueda es "tarifas" (B5: D11)
- El número de columna es 3, impuesto acumulativo
- El tipo de coincidencia es 1 = coincidencia aproximada
VLOOKUP(inc,rates,3,1) // returns 4,543
Con un ingreso imponible de $ 50,000, BUSCARV, en modo de coincidencia aproximada, coincide con 39,475 y devuelve 4,543, el impuesto total hasta $ 39,475.
El segundo BUSCARV calcula los ingresos restantes a gravar:
(inc-VLOOKUP(inc,rates,1,1)) // returns 10,525
calculado así:
(50.000-39.475) = 10.525
Finalmente, el tercer VLOOKUP obtiene la tasa impositiva marginal (máxima):
VLOOKUP(inc,rates,2,1) // returns 22%
Esto se multiplica por los ingresos calculados en el paso anterior. La fórmula completa se resuelve así:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1) =4,543+(10525)*22% =6,859
Tasas marginales y efectivas
La celda G6 contiene la tasa marginal máxima, calculada con BUSCARV:
=VLOOKUP(inc,rates,2,1) // returns 22%
La tasa impositiva efectiva en G7 es el impuesto total dividido por la renta imponible:
=G5/inc // returns 13.7%
Nota: encontré esta fórmula en el blog de Jeff Lenning en la Universidad de Excel. Es un gran ejemplo de cómo VLOOKUP se puede usar en el modo de coincidencia aproximada, y también cómo VLOOKUP se puede usar varias veces en la misma fórmula.
