Fórmula de Excel: enumere los números más frecuentes -

Tabla de contenido

Fórmula genérica

(=MODE(IF(1-ISNUMBER(MATCH(data,exp_rng,0)),data)))

Resumen

Para enumerar los números que ocurren con más frecuencia en una columna (es decir, los más comunes, los segundos más comunes, los terceros más comunes, etc.), puede crear una fórmula de matriz basada en cuatro funciones de Excel: SI, MODO, COINCIDIR e ESNUMERO. En el ejemplo que se muestra, la fórmula en D5 es:

(=MODE(IF(1-ISNUMBER(MATCH(data,$D$4:D4,0)),data)))

donde "datos" es el rango con nombre B5: B16. Luego, la fórmula se copia en las filas debajo de D5 para generar la lista deseada de los números más frecuentes.

Nota: esta es una fórmula de matriz y debe ingresarse con control + shift + enter.

Explicación

El núcleo de esta fórmula es la función MODE, que devuelve el número que aparece con más frecuencia en un rango o matriz. El resto de la fórmula simplemente construye una matriz filtrada para que MODE la use en cada fila. El rango de expansión $ D $ 4: D4 funciona para excluir los números que ya se muestran en $ D $ 4: D4.

Trabajando de adentro hacia afuera:

  1. La función COINCIDIR se usa primero, verifique todos los números en el rango nombrado "datos" con los números existentes en el rango de expansión $ D $ 4: D4
  2. ISNUMBER convierte los valores coincidentes en VERDADERO y los valores no coincidentes en FALSO
  3. 1-NUMBER invierte la matriz y la operación matemática genera unos y ceros
  4. IF usa la salida de matriz del n. ° 3 anterior para filtrar la lista original de valores, excluyendo los números que ya están en $ D $ 4: D4
  5. La función MODE devuelve el número más frecuente en la salida de la matriz en el paso # 4

En la celda D5, no se produce ningún filtrado y el resultado de cada paso anterior se ve así:

(#N/A;#N/A;#N/A;#N/A;#N/A;#N/A;#N/A;#N/A;#N/A;#N/A;#N/A;#N/A) (FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE) (1;1;1;1;1;1;1;1;1;1;1;1) (93;92;93;94;95;96;97;98;99;93;97;95) 93

En la celda D6, con 93 ya en D5, la salida se ve así:

(2;#N/A;2;#N/A;#N/A;#N/A;#N/A;#N/A;#N/A;2;#N/A;#N/A) (TRUE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE) (0;1;0;1;1;1;1;1;1;0;1;1) (FALSE;92;FALSE;94;95;96;97;98;99;FALSE;97;95) 95

Manejo de errores

La función MODE devolverá el error # N / A cuando no hay modo. A medida que copia la fórmula en las filas siguientes, es probable que se encuentre con el error # N / A. Para atrapar este error y devolver una cadena vacía ("") en su lugar, puede usar IFERROR así:

=IFERROR(MODE(IF(1-ISNUMBER(MATCH(data,$D$4:D4,0)),data)),"")

Articulos interesantes...