Fórmula genérica
=FILTER(data,range>=LARGE(range,n))
Resumen
Para filtrar un conjunto de datos para mostrar los n valores principales, puede usar la función FILTRO junto con la función GRANDE. En el ejemplo que se muestra, la fórmula en F5 es:
=FILTER(data,score>=LARGE(score,3))
donde los datos (B5: D16) y la puntuación (D5: D16) se denominan rangos.
Explicación
Esta fórmula usa la función FILTRO para recuperar datos basados en una prueba lógica construida con la función GRANDE.
La función LARGE es una forma sencilla de obtener el enésimo valor más grande de un rango. Simplemente proporcione un rango para el primer argumento (matriz) y un valor para n como segundo argumento (k):
=LARGE(range,1) // 1st largest =LARGE(range,2) // 2nd largest =LARGE(range,3) // 3rd largest
En este ejemplo, la lógica de FILTER se construye con este fragmento:
score>=LARGE(score,3)
que devuelve VERDADERO cuando una puntuación es mayor o igual que la tercera puntuación más alta. Dado que hay 12 celdas en el rango D5: D16, esta expresión devuelve una matriz de 12 valores VERDADERO y FALSO en una matriz como esta:
(FALSE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE)
Esta matriz se devuelve directamente a la función FILTRO como argumento de inclusión, donde se utiliza para filtrar los datos. Solo las filas en las que el resultado es VERDADERO se convierten en el resultado final. El resultado de la fórmula en F5 incluye los 3 puntajes más altos en los datos, que se extienden al rango F5: H7.
Ordenar resultados por puntuación
De forma predeterminada, FILTER devolverá registros coincidentes en el mismo orden en que aparecen en los datos de origen. Para ordenar los resultados en orden descendente por puntaje, puede anidar la fórmula FILTRO original dentro de la función CLASIFICAR de esta manera:
=SORT(FILTER(data,score>=LARGE(score,3)),3,-1)
Aquí, FILTER devuelve los resultados directamente a la función SORT como argumento de matriz. El índice de clasificación se establece en 3 (puntuación) y el orden de clasificación se establece en -1, para orden descendente.
