Fórmula genérica
=IF(criteria,formula(),"")
Resumen
Para ejecutar una fórmula solo cuando una o más celdas no están en blanco, puede usar la función SI con un criterio lógico apropiado. En el ejemplo que se muestra, la fórmula en E5 es:
=IF(COUNT(C5:C7)=3,SUM(C5:C7),"")
Dado que C7 no tiene ningún valor en la pantalla anterior, la fórmula no muestra ningún resultado. En la siguiente pantalla, C7 contiene un número y se muestra la suma:
Explicación
El objetivo de este ejemplo es verificar la entrada antes de calcular un resultado. El punto clave a entender es que se puede sustituir cualquier fórmula válida. La función SUM se utiliza solo como ejemplo. La lógica también se puede ajustar de muchas formas para adaptarse a la situación.
En el ejemplo que se muestra, estamos usando la función SI junto con la función CONTAR. El criterio es una expresión basada en la función COUNT, que solo cuenta valores numéricos:
COUNT(C5:C7)=3 // returns TRUE or FALSE
Siempre que el rango contenga tres números (es decir, las 3 celdas no están en blanco), el resultado es VERDADERO y SI ejecutará la función SUMA. De lo contrario, el resultado es FALSO y SI devuelve una cadena vacía (""). Dado que C7 no tiene ningún valor en la pantalla anterior, la fórmula no muestra ningún resultado.
Hay muchas formas de comprobar si hay celdas en blanco y a continuación se explican varias opciones.
Con COUNTBLANK
La función COUNTBLANK cuenta las celdas vacías en un rango, por lo que podemos escribir una fórmula un poco más compacta como esta:
=IF(COUNTBLANK(C5:C7),"",SUM(C5:C7))
Si COUNTBLANK devuelve cualquier número excepto cero, la función SI se evaluará como VERDADERO y no devolverá nada (""). Si COUNTBLANK devuelve cero, IF se evalúa como FALSE y devuelve la suma.
Con ISBLANK
En el ejemplo que se muestra, las celdas de entrada están todas en el mismo rango contiguo. En los casos en que las celdas no estén juntas, puede usar una fórmula como esta:
=IF(OR(ISBLANK(C5),ISBLANK(C6),ISBLANK(C7)),"",SUM(C5:C7))
Este ejemplo adopta un enfoque literal con la función ESBLANCO. Debido a que queremos verificar las tres celdas al mismo tiempo, necesitamos usar ISBLANK tres veces dentro de la función OR. Esta es la prueba lógica dentro de IF:
OR(ISBLANK(C5),ISBLANK(C6),ISBLANK(C7)
Cuando OR devuelve VERDADERO (al menos una celda está vacía), SI devuelve una cadena vacía (""). Cuando OR devuelve FALSO (no hay celdas en blanco), SI ejecuta la función SUMA y devuelve el resultado:
SUM(C5:C7)
Con operadores lógicos
La función ISBLANK se puede reemplazar con operadores lógicos estándar como este:
=IF(OR(C5="",C6="",C7=""),"",SUM(C5:C7))
Alternativamente, podemos combinar el operador no igual a () con la función AND de esta manera:
=IF(AND(C5"",C6"",C7""),SUM(C5:C7),"")
Observe que la función SUMA se ha movido al resultado VERDADERO. Solo se ejecutará si C5, C6 y C5 no están vacíos.
Con COUNTA
Finalmente, puede usar la función CONTAR para verificar la entrada numérica o de texto:
=IF(COUNTA(C5:C7)=3,SUM(C5:C7),"")
Siempre que el rango C5: C5 contenga tres valores (números o texto), el resultado será VERDADERO y se ejecutará la función SUMA. Esto realmente no tiene sentido para el ejemplo que se muestra (que requiere entrada numérica) pero se puede utilizar en otras situaciones.
