Fórmula genérica
=INT(end-start)&" days "&TEXT(end-start,"h"" hrs ""m"" mins """)
Resumen
Para calcular y mostrar los días, horas y minutos entre dos fechas, puede usar la función TEXTO con un poco de ayuda de la función INT. En el ejemplo que se muestra, la fórmula en D5 es:
=INT(C5-B5)&" days "&TEXT(C5-B5,"h"" hrs ""m"" mins """)
Explicación
La mayor parte del trabajo en esta fórmula lo realiza la función TEXTO, que aplica un formato numérico personalizado para horas y minutos a un valor creado restando la fecha de inicio de la fecha de finalización.
TEXT(C5-B5,"h"" hrs ""m"" mins """)
Este es un ejemplo de cómo incrustar texto en un formato de número personalizado, y este texto debe estar rodeado por un par adicional de comillas dobles. Sin las comillas dobles adicionales, el formato de texto personalizado se ve así:
h "hrs" m "min"
El valor de los días se calcula con la función INT, que simplemente devuelve la parte entera de la fecha de finalización menos la fecha de inicio:
INT(C5-B5) // get day value
Nota: Aunque puede usar "d" en un formato de número personalizado para los días, el valor se restablecerá a cero cuando los días sean mayores que 31.
Incluir segundos
Para incluir segundos, puede ampliar el formato de número personalizado de esta manera:
=INT(C5-B5)&" days "&TEXT(C5-B5,"h"" hrs ""m"" mins ""s"" secs""")
Total de días, horas y minutos entre fechas
Para obtener el total de días, horas y minutos entre un conjunto de fechas de inicio y finalización, puede adaptar la fórmula usando SUMPRODUCT de esta manera:
=INT(SUMPRODUCT(ends-starts))&" days "&TEXT(SUMPRODUCT(ends-starts),"h"" hrs ""m"" mins """)
donde "finaliza" representa el rango de fechas de finalización y "comienza" representa el rango de fechas de inicio. En el ejemplo que se muestra, D11 contiene esta fórmula:
=INT(SUMPRODUCT(C5:C9-B5:B9))&" days "&TEXT(SUMPRODUCT(C5:C9-B5:B9),"h"" hrs ""m"" mins """)
