Fórmula genérica
=MIN(UNIQUE(range,0,1))
Resumen
Para encontrar el valor único mínimo en un conjunto de datos, puede usar la función ÚNICA junto con la función MIN. En el siguiente ejemplo, la fórmula en E5 es:
=MIN(UNIQUE(data,0,1))
donde "datos" es el rango con nombre B5: B14.
En versiones anteriores de Excel, puede usar una fórmula de matriz basada en las funciones MIN, IF y COUNTIF como se explica a continuación.
Explicación
El objetivo de este ejemplo es devolver el valor mínimo que es único, es decir, el valor mínimo que aparece solo una vez en los datos.
La función ÚNICA, nueva en Excel 365, devolverá una lista única de valores de un conjunto de datos. De forma predeterminada, esta es una lista de cualquier valor que aparece una o más veces en los datos.
UNIQUE tiene un tercer argumento opcional llamado "exact_once" que limitará los resultados a los valores que ocurren una sola vez en los datos de origen. Para habilitar esta función, el argumento debe establecerse en VERDADERO o 1.
Trabajando de adentro hacia afuera, la función ÚNICA se configura así:
UNIQUE(data,0,1)
Para la matriz, proporcionamos los datos del rango con nombre . Para el argumento by_col, usamos cero (0), ya que queremos valores únicos por filas, no columnas. Finalmente, para exact_once, proporcionamos 1, ya que solo queremos valores que ocurren solo una vez en los datos de origen.
Configurado de esta manera, UNIQUE devuelve los 4 valores que aparecen solo una vez:
(700;600;500;300) // result from unique
Esta matriz se devuelve directamente a la función MIN, que devuelve el valor mínimo, 300, como resultado final:
=MIN((700;600;500;300)) // returns 300
Fórmula de matriz con COUNTIF
Si está utilizando una versión de Excel sin la función ÚNICA, puede encontrar el valor único mínimo con una fórmula de matriz basada en las funciones CONTAR.SI, MIN y SI.
(=MIN(IF(COUNTIF(data,data)=1,data)))
Esta es una fórmula de matriz y debe ingresarse con control + shift + enter, excepto en Excel 365.
Trabajando desde adentro hacia afuera, la función CONTAR.SI se usa para generar un recuento de cada valor en los datos como este:
COUNTIF(data,data) // count all values
Debido a que hay 10 valores en los datos del rango con nombre , COUNTIF devuelve una matriz de 10 resultados:
(2;1;1;2;1;2;2;2;1;2)
Esta matriz contiene el recuento de cada valor. A continuación, probamos la matriz para valores iguales a 1:
(2;1;1;2;1;2;2;2;1;2)=1
Nuevamente, obtenemos una matriz con 10 resultados:
(FALSE;TRUE;TRUE;FALSE;TRUE;FALSE;FALSE;FALSE;TRUE;FALSE)
Cada valor VERDADERO corresponde a un valor en los datos de origen que aparece solo una vez. Esta matriz se envía directamente a la función IF, que la usa como un filtro. Solo los valores en los datos asociados con VERDADERO entran en la matriz devuelta por IF, todos los demás valores son FALSOS.
(FALSE;700;600;FALSE;500;FALSE;FALSE;FALSE;300;FALSE)
Esta matriz se devuelve directamente a la función MIN que automáticamente ignora los valores lógicos y devuelve el mínimo de valores restantes, 300, como resultado final.
