Fórmula genérica
=INDEX(range1,MATCH(TRUE,EXACT(A1,range2),0))
Resumen
Para realizar una búsqueda que distingue entre mayúsculas y minúsculas, puede utilizar la función EXACT junto con INDEX y MATCH. En el programa de ejemplo, la fórmula en F5 es:
=INDEX(C5:C14,MATCH(TRUE,EXACT(E5,B5:B14),0))
que devuelve 39, la edad de "JILL SMITH".
Nota: esta es una fórmula de matriz y debe ingresarse con Control + Shift + Enter, excepto en Excel 365.
Explicación
En esencia, esta es una fórmula de INDICE y COINCIDIR, con la función EXACTA utilizada dentro de COINCIDIR para realizar una coincidencia sensible a mayúsculas y minúsculas.
Trabajando desde adentro hacia afuera, EXACT está configurado para comparar el valor en E5 con nombres en el rango B5: B14:
EXACT(E5,B5:B14) // returns array of results
La función EXACTA realiza una comparación que distingue entre mayúsculas y minúsculas y devuelve VERDADERO o FALSO como resultado. Solo los valores que coincidan exactamente devolverán VERDADERO. Debido a que estamos comprobando el nombre en E5 ("JILL SMITH") con los diez nombres en el rango B5: B14, obtenemos una matriz de diez valores VERDADEROS y FALSOS como este:
(FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE)
Esta matriz se devuelve directamente a la función COINCIDIR como lookup_array así:
MATCH(TRUE,(FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE),0)
Con un valor de búsqueda de VERDADERO, COINCIDIR devuelve 5, ya que el único VERDADERO en la matriz está en la quinta posición. Observe también que match_type se establece en cero (0) para forzar una coincidencia exacta.
La función COINCIDIR devuelve un resultado directamente a la función INDICE como el número de fila, por lo que ahora podemos reescribir la fórmula de esta manera:
=INDEX(C5:C14,5) // returns 39
INDICE devuelve la edad en la quinta fila, 39, como resultado final.
Debido a que usar la función EXACTA como esta es una operación de matriz, la fórmula es una fórmula de matriz y debe ingresarse con Control + Shift + Enter, excepto en Excel 365.
Con XLOOKUP
En Excel 365, la función XLOOKUP se puede configurar para realizar una búsqueda que distingue entre mayúsculas y minúsculas de una manera similar a esta:
=XLOOKUP(TRUE,EXACT(J5,B5:B14),C5:C14,"na",0)
Observe que el valor de búsqueda y la matriz de búsqueda están configurados como la función COINCIDIR anterior. Después de ejecuciones EXACTAS, tenemos:
=XLOOKUP(TRUE,(FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE),C5:C14,"na",0)
y BUSCAR X devuelve el quinto elemento del rango C5: C14 (39) como resultado final.
