Fórmula genérica
=ADDRESS(ROW(nr),COLUMN(nr))&":"&ADDRESS(ROW(nr)+ROWS(nr)-1,COLUMN(nr)+COLUMNS(nr)-1)
Resumen
Para obtener la dirección completa de un rango con nombre con una fórmula de Excel, puede usar la función DIRECCIÓN junto con las funciones FILA y COLUMNA. En el ejemplo que se muestra, la fórmula en G5 es:
=ADDRESS(ROW(data),COLUMN(data),4)&":"&ADDRESS(ROW(data)+ROWS(data)-1,COLUMN(data)+COLUMNS(data)-1,4)
donde "datos" es el rango con nombre B5: D10
Explicación
El núcleo de esta fórmula es la función ADDRESS, que se utiliza para devolver una dirección de celda basada en una fila y columna determinadas. Desafortunadamente, la fórmula se complica un poco porque necesitamos usar DIRECCIÓN dos veces: una vez para obtener la dirección de la primera celda del rango y otra para obtener la dirección de la última celda del rango. Los dos resultados se unen con la concatenación y el operador de rango (:) y el rango completo se devuelve como texto.
Para obtener la primera celda del rango, usamos esta expresión:
=ADDRESS(ROW(data),COLUMN(data))
FILA devuelve el primer número de fila asociado con el rango, 5 *.
COLUMNA devuelve el primer número de columna asociado con el rango, 2.
Con abs_num establecido en 4 (relativo), ADDRESS devuelve el texto "B5".
=ADDRESS(5,2,4) // returns "B5"
Para obtener la última celda del rango, usamos esta expresión:
=ADDRESS(ROW(data)+ROWS(data)-1,COLUMN(data)+COLUMNS(data)-1,4)
Consulte esta página para obtener una explicación detallada.
Básicamente, seguimos la misma idea anterior, agregando matemáticas simples para calcular la última fila y la última columna del rango, que se introducen como antes en ADDRESS con abs_num establecido en 4. Esto se reduce a la siguiente expresión, que devuelve el texto " D10 ":
=ADDRESS(10,4,4) // returns "D10"
Ambos resultados se concatenan con dos puntos para obtener una dirección de rango final como texto:
="B5"&":"&"D10" ="B5:D10
Rango con nombre de otra celda
Para obtener una dirección para un rango con nombre en otra celda, deberá usar la función INDIRECTO. Por ejemplo, para obtener la dirección de un nombre en A1, usaría:
=ADDRESS(ROW(INDIRECT(A1)),COLUMN(INDIRECT(A1)))&":"&ADDRESS(ROW(INDIRECT(A1))+ROWS(INDIRECT(A1))-1,COLUMN(INDIRECT(A1))+COLUMNS(INDIRECT(A1))-1)
Establezca abs_num en 4 dentro de ADDRESS para obtener una dirección relativa.
* En realidad, en todos los casos en los que usemos FILA y COLUMNA con un rango con nombre de varias celdas, obtendremos una matriz de números en lugar de un solo valor. Sin embargo, dado que no estamos usando una fórmula de matriz, el procesamiento se limita al primer elemento de estas matrices.
