Fórmula genérica
=SUMPRODUCT((MONTH(dates)=month)*amounts)
Resumen
Para sumar datos por mes, ignorando el año, puede usar una fórmula basada en las funciones SUMPRODUCTO y MES. En el ejemplo que se muestra, la fórmula en H6 es:
=SUMPRODUCT((MONTH(dates)=3)*amounts)
El resultado es un total de todas las ventas en marzo, ignorando el año.
Explicación
Este conjunto de datos contiene más de 2900 registros y la fórmula anterior utiliza dos rangos con nombre:
dates = B5:B2932 amounts = E5:E2932
Dentro de la función SUMPRODUCTO, la función MES se usa para extraer el número de mes para cada fecha en el conjunto de datos y compararlo con el número 3:
(MONTH(dates)=3)
Si asumimos un pequeño conjunto de datos que enumera 3 fechas cada una en enero, febrero y marzo (en ese orden), el resultado sería una matriz que contiene nueve números como este:
(1;1;1;2;2;2;3;3;3)
donde cada número es el "número de mes" para una fecha. Cuando los valores se comparan con 3, el resultado es una matriz como esta:
(FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;TRUE;TRUE;TRUE)
Luego, esta matriz se multiplica por los valores de cantidad asociados con cada fecha de marzo. Si asumimos que las nueve cantidades son iguales a 100, la operación se ve así:
(0;0;0;0;0;0;1;1;1) * (100;100;100;100;100;100;100;100;100)
Observe que la operación matemática cambia los valores VERDADERO FALSO a unos y ceros. Después de la multiplicación, tenemos una única matriz en SUMPRODUCT:
=SUMPRODUCT((0;0;0;0;0;0;100;100;100))
Tenga en cuenta que las únicas cantidades supervivientes están asociadas con marzo, el resto es cero.
Finalmente, SUMPRODUCT devuelve la suma de todos los elementos: 300 en el ejemplo abreviado anterior y 25.521 en la captura de pantalla con datos reales.
Contar por mes ignorando el año
Para obtener un recuento por mes ignorando el año, puede usar SUMPRODUCT de esta manera:
=SUMPRODUCT(--(MONTH(dates)=3))
Promedio por mes ignorando el año
Para calcular y promediar por mes ignorando el año, combine las dos fórmulas SUMPRODUCT anteriores de esta manera:
=SUMPRODUCT((MONTH(dates)=3)*amounts)/SUMPRODUCT(--(MONTH(dates)=3))
